Mapas de Contornos da Função - Cálculo Numérico

# MAPA DE CONTORNOS DA FUN��O |p(z)|

#

# Defina os coeficientes do polin�mio abaixo, entre aspas, na ordem a_0, a_1, ..., a_n

# O exemplo abaixo mostra os coeficientes do polin�mio p(z)=z**5-1

a="1.275 0.46 -1.73 0 1"

#

# Defina o valor da cota de Kojima para o raio do disco centrado na origem que cont�m todos

# os zeros do polin�mio

kojima=2

#

# ATEN��O! N�o altere nenhuma linha a partir daqui.

#

# Defini��o da fun��o z(x,y) para obter um n�mero complexo com partes real e imagin�ria x e y, resp.

#

z(x,y) = x*{1,0}+y*{0,1}

#

# Defini��o de par�metros para mapa de contornos e paleta de cores

#

set isosample 250

set contour

set hidden3d

set view map

set pm3d

set palette model HSV

set palette rgbformulae 3,2,2

set logscale cb

unset clabel

#

# Monta a string que representa o polin�mio

#

set macros

s = word(a,1)

do for [i=2:words(a)] { s = sprintf("%s+(%s)*z(x,y)**%d",s,word(a,i),(i-1))}

p(x,y) = @s

#

# Desenha o mapa de contornos

#

set title s

set xlabel "x"

set ylabel "y"

splot [x=-kojima:kojima] [y=-kojima:kojima] abs(p(x,y))

#

# Desabilita macros

#

unset macros